gallium: Add SCons as alternative build system for Gallium.

9 files changed, 875 insertions, 0 deletions

diff --git a/.gitignore b/.gitignore
index 033e6e10bd..bf50291fc1 100644
--- a/.gitignore
+++ b/.gitignore
@@ -7,3 +7,5 @@ depend
 depend.bak
 lib
 lib64
+.sconsign*
+config.py
diff --git a/SConstruct b/SConstruct
new file mode 100644
index 0000000000..db6161ed51
--- /dev/null
+++ b/SConstruct
@@ -0,0 +1,214 @@
+#######################################################################
+# Top-level SConstruct
+
+import os
+import sys
+
+
+#######################################################################
+# Configuration options
+#
+# For example, invoke scons as 
+#
+#   scons debug=1 dri=0 x86=1
+#
+# to set configuration variables. Or you can write those options to a file
+# named config.py:
+#
+#   # config.py
+#   debug=1
+#   dri=0
+#   x86=1
+# 
+# Invoke
+#
+#   scons -h
+#
+# to get the full list of options. See scons manpage for more info.
+#  
+
+# TODO: auto-detect defaults
+opts = Options('config.py')
+opts.Add(BoolOption('debug', 'build debug version', False))
+opts.Add(BoolOption('dri', 'build dri drivers', False))
+opts.Add(EnumOption('machine', 'use machine-specific assembly code', 'x86',
+                     allowed_values=('generic', 'x86', 'x86-64')))
+
+env = Environment(options = opts)
+Help(opts.GenerateHelpText(env))
+
+# for debugging
+#print env.Dump()
+
+if 1:
+	# platform will be typically 'posix' or 'win32' 
+	platform = env['PLATFORM']
+else:
+	# platform will be one of 'linux', 'freebsd', 'win32', 'darwin', etc.
+	platform = sys.platform
+	if platform == 'linux2':
+		platform = 'linux' 
+
+# replicate options values in local variables
+debug = env['debug']
+dri = env['dri']
+machine = env['machine']
+
+# derived options
+x86 = machine == 'x86'
+gcc = platform == 'posix'
+msvc = platform == 'win32'
+
+Export([
+	'debug', 
+	'x86', 
+	'dri', 
+	'platform',
+	'gcc',
+	'msvc',
+])
+
+
+#######################################################################
+# Environment setup
+#
+# TODO: put the compiler specific settings in seperate files
+# TODO: auto-detect as much as possible
+
+         
+# Optimization flags
+if gcc:
+	if debug:
+		env.Append(CFLAGS = '-O0 -g3')
+		env.Append(CXXFLAGS = '-O0 -g3')
+	else:
+		env.Append(CFLAGS = '-O3 -g3')
+		env.Append(CXXFLAGS = '-O3 -g3')
+
+	env.Append(CFLAGS = '-Wall -Wmissing-prototypes -std=c99 -ffast-math -pedantic')
+	env.Append(CXXFLAGS = '-Wall -pedantic')
+	
+	# Be nice to Eclipse
+	env.Append(CFLAGS = '-fmessage-length=0')
+	env.Append(CXXFLAGS = '-fmessage-length=0')
+
+# Defines
+env.Append(CPPDEFINES = [
+	'_POSIX_SOURCE',
+	('_POSIX_C_SOURCE', '199309L'), 
+	'_SVID_SOURCE',
+	'_BSD_SOURCE', 
+	'_GNU_SOURCE',
+	
+	'PTHREADS',
+	'HAVE_ALIAS', 
+	'HAVE_POSIX_MEMALIGN',
+])
+
+if debug:
+	env.Append(CPPDEFINES = ['DEBUG'])
+else:
+	env.Append(CPPDEFINES = ['NDEBUG'])
+
+
+# Includes
+env.Append(CPPPATH = [
+	'#/include',
+	'#/src/mesa',
+	'#/src/mesa/main',
+	'#/src/mesa/pipe',
+	
+	'/usr/X11R6/include',
+])
+
+
+# x86 assembly
+if x86:
+	env.Append(CPPDEFINES = [
+		'USE_X86_ASM', 
+		'USE_MMX_ASM',
+		'USE_3DNOW_ASM',
+		'USE_SSE_ASM',
+	])
+	if gcc:	
+		env.Append(CFLAGS = '-m32')
+		env.Append(CXXFLAGS = '-m32')
+
+env.Append(LIBPATH = ['/usr/X11R6/lib'])
+
+env.Append(LIBS = [
+	'm',
+	'pthread',
+	'expat',
+	'dl',
+])
+
+# DRI
+if dri:
+	env.ParseConfig('pkg-config --cflags --libs libdrm')
+	env.Append(CPPDEFINES = [
+		('USE_EXTERNAL_DXTN_LIB', '1'), 
+		'IN_DRI_DRIVER',
+		'GLX_DIRECT_RENDERING',
+		'GLX_INDIRECT_RENDERING',
+	])
+
+# libGL
+if 1:
+	env.Append(LIBS = [
+		'X11',
+		'Xext',
+		'Xxf86vm',
+		'Xdamage',
+		'Xfixes',
+	])
+
+Export('env')
+
+
+#######################################################################
+# Convenience Library Builder
+# based on the stock StaticLibrary and SharedLibrary builders
+
+def createConvenienceLibBuilder(env):
+    """This is a utility function that creates the ConvenienceLibrary
+    Builder in an Environment if it is not there already.
+
+    If it is already there, we return the existing one.
+    """
+
+    try:
+        convenience_lib = env['BUILDERS']['ConvenienceLibrary']
+    except KeyError:
+        action_list = [ Action("$ARCOM", "$ARCOMSTR") ]
+        if env.Detect('ranlib'):
+            ranlib_action = Action("$RANLIBCOM", "$RANLIBCOMSTR")
+            action_list.append(ranlib_action)
+
+        convenience_lib = Builder(action = action_list,
+                                  emitter = '$LIBEMITTER',
+                                  prefix = '$LIBPREFIX',
+                                  suffix = '$LIBSUFFIX',
+                                  src_suffix = '$SHOBJSUFFIX',
+                                  src_builder = 'SharedObject')
+        env['BUILDERS']['ConvenienceLibrary'] = convenience_lib
+        env['BUILDERS']['Library'] = convenience_lib
+
+    return convenience_lib
+
+createConvenienceLibBuilder(env)
+
+
+#######################################################################
+# Invoke SConscripts
+
+# Put build output in a separate dir
+# TODO: make build_dir depend on platform and build type (check  
+#       http://www.scons.org/wiki/AdvancedBuildExample for an example)
+build_dir = 'build'
+
+SConscript(
+	'src/mesa/SConscript',
+	build_dir = build_dir,
+	duplicate = 0 # http://www.scons.org/doc/0.97/HTML/scons-user/x2261.html
+)
diff --git a/src/mesa/SConscript b/src/mesa/SConscript
new file mode 100644
index 0000000000..70a98f3129
--- /dev/null
+++ b/src/mesa/SConscript
@@ -0,0 +1,435 @@
+#######################################################################
+# SConscript for mesa
+#
+# TODO: Split this into per-module SConscripts 
+
+
+Import('*')
+
+
+#######################################################################
+# Core sources
+
+MAIN_SOURCES = [
+	'main/api_arrayelt.c',
+	'main/api_loopback.c',
+	'main/api_noop.c',
+	'main/api_validate.c',
+	'main/accum.c',
+	'main/attrib.c',
+	'main/arrayobj.c',
+	'main/blend.c',
+	'main/bufferobj.c',
+	'main/buffers.c',
+	'main/clip.c',
+	'main/colortab.c',
+	'main/context.c',
+	'main/convolve.c',
+	'main/debug.c',
+	'main/depth.c',
+	'main/depthstencil.c',
+	'main/dlist.c',
+	'main/drawpix.c',
+	'main/enable.c',
+	'main/enums.c',
+	'main/eval.c',
+	'main/execmem.c',
+	'main/extensions.c',
+	'main/fbobject.c',
+	'main/feedback.c',
+	'main/ffvertex_prog.c',
+	'main/fog.c',
+	'main/framebuffer.c',
+	'main/get.c',
+	'main/getstring.c',
+	'main/hash.c',
+	'main/hint.c',
+	'main/histogram.c',
+	'main/image.c',
+	'main/imports.c',
+	'main/light.c',
+	'main/lines.c',
+	'main/matrix.c',
+	'main/mipmap.c',
+	'main/mm.c',
+	'main/pixel.c',
+	'main/points.c',
+	'main/polygon.c',
+	'main/queryobj.c',
+	'main/rastpos.c',
+	'main/rbadaptors.c',
+	'main/renderbuffer.c',
+	'main/shaders.c',
+	'main/state.c',
+	'main/stencil.c',
+	'main/texcompress.c',
+	'main/texcompress_s3tc.c',
+	'main/texcompress_fxt1.c',
+	'main/texenvprogram.c',
+	'main/texformat.c',
+	'main/teximage.c',
+	'main/texobj.c',
+	'main/texrender.c',
+	'main/texstate.c',
+	'main/texstore.c',
+	'main/varray.c',
+	'main/vtxfmt.c',
+]
+
+GLAPI_SOURCES = [
+	'main/dispatch.c',
+	'glapi/glapi.c',
+	'glapi/glthread.c',
+]
+
+MATH_SOURCES = [
+	'math/m_debug_clip.c',
+	'math/m_debug_norm.c',
+	'math/m_debug_xform.c',
+	'math/m_eval.c',
+	'math/m_matrix.c',
+	'math/m_translate.c',
+	'math/m_vector.c',
+	'math/m_xform.c',
+]
+
+VBO_SOURCES = [
+	'vbo/vbo_context.c',
+	'vbo/vbo_exec.c',
+	'vbo/vbo_exec_api.c',
+	'vbo/vbo_exec_array.c',
+	'vbo/vbo_exec_draw.c',
+	'vbo/vbo_exec_eval.c',
+	'vbo/vbo_rebase.c',
+	'vbo/vbo_split.c',
+	'vbo/vbo_split_copy.c',
+	'vbo/vbo_split_inplace.c',
+	'vbo/vbo_save.c',
+	'vbo/vbo_save_api.c',
+	'vbo/vbo_save_draw.c',
+	'vbo/vbo_save_loopback.c',
+]
+
+VF_SOURCES = [
+	'vf/vf.c',
+	'vf/vf_generic.c',
+	'vf/vf_sse.c',
+]
+
+DRAW_SOURCES = [
+	'pipe/draw/draw_clip.c',
+	'pipe/draw/draw_context.c',
+	'pipe/draw/draw_cull.c',
+	'pipe/draw/draw_debug.c',
+	'pipe/draw/draw_flatshade.c',
+	'pipe/draw/draw_offset.c',
+	'pipe/draw/draw_prim.c',
+	'pipe/draw/draw_stipple.c',
+	'pipe/draw/draw_twoside.c',
+	'pipe/draw/draw_unfilled.c',
+	'pipe/draw/draw_validate.c',
+	'pipe/draw/draw_vbuf.c',
+	'pipe/draw/draw_vertex.c',
+	'pipe/draw/draw_vertex_cache.c',
+	'pipe/draw/draw_vertex_fetch.c',
+	'pipe/draw/draw_vertex_shader.c',
+	'pipe/draw/draw_vertex_shader_llvm.c',
+	'pipe/draw/draw_vf.c',
+	'pipe/draw/draw_vf_generic.c',
+	'pipe/draw/draw_vf_sse.c',
+	'pipe/draw/draw_wide_prims.c',
+]
+
+TGSIEXEC_SOURCES = [
+	'pipe/tgsi/exec/tgsi_exec.c',
+	'pipe/tgsi/exec/tgsi_sse2.c',
+]
+
+TGSIUTIL_SOURCES = [
+	'pipe/tgsi/util/tgsi_build.c',
+	'pipe/tgsi/util/tgsi_dump.c',
+	'pipe/tgsi/util/tgsi_parse.c',
+	'pipe/tgsi/util/tgsi_util.c',
+]
+
+STATECACHE_SOURCES = [
+	'pipe/cso_cache/cso_hash.c',
+	'pipe/cso_cache/cso_cache.c',
+]
+
+PIPEUTIL_SOURCES = [
+	'pipe/util/p_tile.c',
+	'pipe/util/p_util.c',
+]
+
+STATETRACKER_SOURCES = [
+	'state_tracker/st_atom.c',
+	'state_tracker/st_atom_blend.c',
+	'state_tracker/st_atom_clip.c',
+	'state_tracker/st_atom_constbuf.c',
+	'state_tracker/st_atom_depth.c',
+	'state_tracker/st_atom_framebuffer.c',
+	'state_tracker/st_atom_pixeltransfer.c',
+	'state_tracker/st_atom_sampler.c',
+	'state_tracker/st_atom_scissor.c',
+	'state_tracker/st_atom_shader.c',
+	'state_tracker/st_atom_rasterizer.c',
+	'state_tracker/st_atom_stipple.c',
+	'state_tracker/st_atom_texture.c',
+	'state_tracker/st_atom_viewport.c',
+	'state_tracker/st_cb_accum.c',
+	'state_tracker/st_cb_bufferobjects.c',
+	'state_tracker/st_cb_clear.c',
+	'state_tracker/st_cb_flush.c',
+	'state_tracker/st_cb_drawpixels.c',
+	'state_tracker/st_cb_fbo.c',
+	'state_tracker/st_cb_feedback.c',
+	'state_tracker/st_cb_program.c',
+	'state_tracker/st_cb_queryobj.c',
+	'state_tracker/st_cb_rasterpos.c',
+	'state_tracker/st_cb_readpixels.c',
+	'state_tracker/st_cb_strings.c',
+	'state_tracker/st_cb_texture.c',
+	'state_tracker/st_cache.c',
+	'state_tracker/st_context.c',
+	'state_tracker/st_debug.c',
+	'state_tracker/st_draw.c',
+	'state_tracker/st_extensions.c',
+	'state_tracker/st_format.c',
+	'state_tracker/st_framebuffer.c',
+	'state_tracker/st_mesa_to_tgsi.c',
+	'state_tracker/st_program.c',
+	'state_tracker/st_texture.c',
+]
+
+SHADER_SOURCES = [
+	'shader/arbprogparse.c',
+	'shader/arbprogram.c',
+	'shader/atifragshader.c',
+	'shader/grammar/grammar_mesa.c',
+	'shader/nvfragparse.c',
+	'shader/nvprogram.c',
+	'shader/nvvertparse.c',
+	'shader/program.c',
+	'shader/prog_cache.c',
+	'shader/prog_debug.c',
+	'shader/prog_execute.c',
+	'shader/prog_instruction.c',
+	'shader/prog_parameter.c',
+	'shader/prog_print.c',
+	'shader/prog_statevars.c',
+	'shader/programopt.c',
+	'shader/shader_api.c',
+]
+
+SLANG_SOURCES = [
+	'shader/slang/slang_builtin.c',
+	'shader/slang/slang_codegen.c',
+	'shader/slang/slang_compile.c',
+	'shader/slang/slang_compile_function.c',
+	'shader/slang/slang_compile_operation.c',
+	'shader/slang/slang_compile_struct.c',
+	'shader/slang/slang_compile_variable.c',
+	'shader/slang/slang_emit.c',
+	'shader/slang/slang_ir.c',
+	'shader/slang/slang_label.c',
+	'shader/slang/slang_library_noise.c',
+	'shader/slang/slang_link.c',
+	'shader/slang/slang_log.c',
+	'shader/slang/slang_mem.c',
+	'shader/slang/slang_preprocess.c',
+	'shader/slang/slang_print.c',
+	'shader/slang/slang_simplify.c',
+	'shader/slang/slang_storage.c',
+	'shader/slang/slang_typeinfo.c',
+	'shader/slang/slang_vartable.c',
+	'shader/slang/slang_utility.c',
+]
+
+
+#######################################################################
+# Assembly sources
+
+ASM_C_SOURCES = [
+	'x86/common_x86.c',
+	'x86/x86.c',
+	'x86/3dnow.c',
+	'x86/sse.c',
+	'x86/rtasm/x86sse.c',
+	'sparc/sparc.c',
+	'ppc/common_ppc.c',
+	'x86-64/x86-64.c',
+]
+
+X86_SOURCES = [
+	'x86/common_x86_asm.S',
+	'x86/x86_xform2.S',
+	'x86/x86_xform3.S',
+	'x86/x86_xform4.S',
+	'x86/x86_cliptest.S',
+	'x86/mmx_blend.S',
+	'x86/3dnow_xform1.S',
+	'x86/3dnow_xform2.S',
+	'x86/3dnow_xform3.S',
+	'x86/3dnow_xform4.S',
+	'x86/3dnow_normal.S',
+	'x86/sse_xform1.S',
+	'x86/sse_xform2.S',
+	'x86/sse_xform3.S',
+	'x86/sse_xform4.S',
+	'x86/sse_normal.S',
+	'x86/read_rgba_span_x86.S',
+]
+
+X86_API = [
+	'x86/glapi_x86.S',
+]
+
+X86_64_SOURCES = [
+	'x86-64/xform4.S',
+]
+
+X86_64_API = [
+	'x86-64/glapi_x86-64.S',
+]
+
+SPARC_SOURCES = [
+	'sparc/clip.S',
+	'sparc/norm.S',
+	'sparc/xform.S',
+]
+
+SPARC_API = [
+	'sparc/glapi_sparc.S',
+]
+
+if x86:
+	ASM_SOURCES = ASM_C_SOURCES + X86_SOURCES 
+	API_SOURCES = X86_API
+else:
+	ASM_SOURCES = []
+	API_SOURCES = []
+
+
+#######################################################################
+# Driver sources
+
+
+X11_DRIVER_SOURCES = [
+	'pipe/xlib/glxapi.c',
+	'pipe/xlib/fakeglx.c',
+	'pipe/xlib/xfonts.c',
+	'pipe/xlib/xm_api.c',
+	'pipe/xlib/xm_winsys.c',
+	'pipe/xlib/xm_winsys_aub.c',
+	'pipe/xlib/brw_aub.c',
+]
+
+OSMESA_DRIVER_SOURCES = [
+	'drivers/osmesa/osmesa.c',
+]
+
+GLIDE_DRIVER_SOURCES = [
+	'drivers/glide/fxapi.c',
+	'drivers/glide/fxdd.c',
+	'drivers/glide/fxddspan.c',
+	'drivers/glide/fxddtex.c',
+	'drivers/glide/fxsetup.c',
+	'drivers/glide/fxtexman.c',
+	'drivers/glide/fxtris.c',
+	'drivers/glide/fxvb.c',
+	'drivers/glide/fxglidew.c',
+	'drivers/glide/fxg.c',
+]
+
+SVGA_DRIVER_SOURCES = [
+	'drivers/svga/svgamesa.c',
+	'drivers/svga/svgamesa8.c',
+	'drivers/svga/svgamesa15.c',
+	'drivers/svga/svgamesa16.c',
+	'drivers/svga/svgamesa24.c',
+	'drivers/svga/svgamesa32.c',
+]
+
+FBDEV_DRIVER_SOURCES = [
+	'drivers/fbdev/glfbdev.c',
+]
+
+
+### All the core C sources
+
+SOLO_SOURCES = \
+	MAIN_SOURCES + \
+	MATH_SOURCES + \
+	VBO_SOURCES + \
+	VF_SOURCES + \
+	DRAW_SOURCES + \
+	TGSIEXEC_SOURCES + \
+	TGSIUTIL_SOURCES + \
+	PIPEUTIL_SOURCES + \
+	STATECACHE_SOURCES + \
+	STATETRACKER_SOURCES + \
+	SHADER_SOURCES + \
+	ASM_SOURCES + \
+	SLANG_SOURCES
+
+CORE_SOURCES = \
+	GLAPI_SOURCES + API_SOURCES + \
+	SOLO_SOURCES
+
+ALL_SOURCES = \
+	GLAPI_SOURCES + API_SOURCES + \
+	SOLO_SOURCES + \
+	ASM_SOURCES + \
+	X11_DRIVER_SOURCES + \
+	FBDEV_DRIVER_SOURCES + \
+	OSMESA_DRIVER_SOURCES
+
+
+######################################################################
+# Gallium sources
+
+SConscript([
+	'pipe/SConscript',
+])
+
+
+######################################################################
+# libGL
+
+if not dri:
+	STAND_ALONE_DRIVER_SOURCES = \
+		CORE_SOURCES + \
+		X11_DRIVER_SOURCES
+	
+	Import(
+		'softpipe', 
+		'i915simple',
+		'i965simple'
+	)
+	
+	pipe_drivers = [
+		softpipe,
+		i965simple
+	]
+	
+	env.SharedLibrary(
+		target ='GL',
+		source = STAND_ALONE_DRIVER_SOURCES,
+		LIBS = [softpipe, i965simple] + env['LIBS'],
+	)
+
+
+######################################################################
+# Driver sources
+
+if dri:
+	mesa = env.ConvenienceLibrary(
+		target = 'mesa',
+		source = SOLO_SOURCES,
+	)
+	env.Prepend(LIBS = [mesa])
+
+	SConscript([
+		'drivers/dri/SConscript',
+	])
diff --git a/src/mesa/drivers/dri/SConscript b/src/mesa/drivers/dri/SConscript
new file mode 100644
index 0000000000..d32bd08669
--- /dev/null
+++ b/src/mesa/drivers/dri/SConscript
@@ -0,0 +1,48 @@
+Import('*')
+
+drienv = env.Clone()
+
+drienv.Replace(CPPPATH = [
+	'#src/mesa/drivers/dri/common',
+	'#include',
+	'#include/GL/internal',
+	'#src/mesa',
+	'#src/mesa/main',
+	'#src/mesa/glapi',
+	'#src/mesa/math',
+	'#src/mesa/transform',
+	'#src/mesa/shader',
+	'#src/mesa/swrast',
+	'#src/mesa/swrast_setup',
+	'#src/egl/main',
+	'#src/egl/drivers/dri',
+])
+
+drienv.ParseConfig('pkg-config --cflags --libs libdrm')
+
+COMMON_GALLIUM_SOURCES = [
+	'../common/utils.c',
+	'../common/vblank.c',
+	'../common/dri_util.c',
+	'../common/xmlconfig.c',
+]
+
+COMMON_BM_SOURCES = [
+	'../common/dri_bufmgr.c',
+	'../common/dri_drmpool.c',
+]
+
+Export([
+	'drienv',
+	'COMMON_GALLIUM_SOURCES',
+	'COMMON_BM_SOURCES',
+])
+
+# TODO: Installation
+#install: $(LIBNAME)
+#	$(INSTALL) -d $(DRI_DRIVER_INSTALL_DIR)
+#	$(INSTALL) -m 755 $(LIBNAME) $(DRI_DRIVER_INSTALL_DIR)
+
+SConscript([
+	'intel_winsys/SConscript',
+])
diff --git a/src/mesa/drivers/dri/intel_winsys/SConscript b/src/mesa/drivers/dri/intel_winsys/SConscript
new file mode 100644
index 0000000000..a7cc10450e
--- /dev/null
+++ b/src/mesa/drivers/dri/intel_winsys/SConscript
@@ -0,0 +1,41 @@
+Import('*')
+
+env = drienv.Clone()
+
+env.Append(CPPPATH = [
+	'../intel',
+	'server'
+])
+
+#MINIGLX_SOURCES = server/intel_dri.c
+
+pipe_drivers = [
+	softpipe,
+	i915simple
+]
+
+DRIVER_SOURCES = [
+	'intel_winsys_pipe.c',
+	'intel_winsys_softpipe.c',
+	'intel_winsys_i915.c',
+	'intel_batchbuffer.c',
+	'intel_swapbuffers.c',
+	'intel_context.c',
+	'intel_lock.c',
+	'intel_screen.c',
+	'intel_batchpool.c',
+]
+
+sources = \
+	COMMON_GALLIUM_SOURCES + \
+	COMMON_BM_SOURCES + \
+	DRIVER_SOURCES
+
+# DRIVER_DEFINES = -I../intel $(shell pkg-config libdrm --atleast-version=2.3.1 \
+#				&& echo "-DDRM_VBLANK_FLIP=DRM_VBLANK_FLIP")
+
+env.SharedLibrary(
+	target ='i915tex_dri.so',
+	source = sources,
+	LIBS = pipe_drivers + env['LIBS'],
+)
\ No newline at end of file
diff --git a/src/mesa/pipe/SConscript b/src/mesa/pipe/SConscript
new file mode 100644
index 0000000000..d9c20e0100
--- /dev/null
+++ b/src/mesa/pipe/SConscript
@@ -0,0 +1,9 @@
+Import('*')
+
+#env = env.Clone()
+
+SConscript([
+	'softpipe/SConscript',
+	'i915simple/SConscript',
+	'i965simple/SConscript',
+])
diff --git a/src/mesa/pipe/i915simple/SConscript b/src/mesa/pipe/i915simple/SConscript
new file mode 100644
index 0000000000..f5fb96b995
--- /dev/null
+++ b/src/mesa/pipe/i915simple/SConscript
@@ -0,0 +1,29 @@
+Import('*')
+
+env = env.Clone()
+
+i915simple = env.ConvenienceLibrary(
+	target = 'i915simple',
+	source = [
+		'i915_blit.c',
+		'i915_clear.c',
+		'i915_context.c',
+		'i915_debug.c',
+		'i915_debug_fp.c',
+		'i915_flush.c',
+		'i915_fpc_emit.c',
+		'i915_fpc_translate.c',
+		'i915_prim_emit.c',
+		'i915_prim_vbuf.c',
+		'i915_state.c',
+		'i915_state_derived.c',
+		'i915_state_dynamic.c',
+		'i915_state_emit.c',
+		'i915_state_immediate.c',
+		'i915_state_sampler.c',
+		'i915_strings.c',
+		'i915_surface.c',
+		'i915_texture.c',
+	])
+
+Export('i915simple')
diff --git a/src/mesa/pipe/i965simple/SConscript b/src/mesa/pipe/i965simple/SConscript
new file mode 100644
index 0000000000..74621de84c
--- /dev/null
+++ b/src/mesa/pipe/i965simple/SConscript
@@ -0,0 +1,55 @@
+Import('*')
+
+env = env.Clone()
+
+i965simple = env.ConvenienceLibrary(
+	target = 'i965simple',
+	source = [
+		'brw_blit.c',
+		'brw_cc.c',
+		'brw_clip.c',
+		'brw_clip_line.c',
+		'brw_clip_point.c',
+		'brw_clip_state.c',
+		'brw_clip_tri.c',
+		'brw_clip_util.c',
+		'brw_context.c',
+		'brw_curbe.c',
+		'brw_draw.c',
+		'brw_draw_upload.c',
+		'brw_eu.c',
+		'brw_eu_debug.c',
+		'brw_eu_emit.c',
+		'brw_eu_util.c',
+		'brw_flush.c',
+		'brw_gs.c',
+		'brw_gs_emit.c',
+		'brw_gs_state.c',
+		'brw_misc_state.c',
+		'brw_sf.c',
+		'brw_sf_emit.c',
+		'brw_sf_state.c',
+		'brw_shader_info.c',
+		'brw_state.c',
+		'brw_state_batch.c',
+		'brw_state_cache.c',
+		'brw_state_pool.c',
+		'brw_state_upload.c',
+		'brw_strings.c',
+		'brw_surface.c',
+		'brw_tex_layout.c',
+		'brw_urb.c',
+		'brw_util.c',
+		'brw_vs.c',
+		'brw_vs_emit.c',
+		'brw_vs_state.c',
+		'brw_wm.c',
+		'brw_wm_decl.c',
+		'brw_wm_glsl.c',
+		'brw_wm_iz.c',
+		'brw_wm_sampler_state.c',
+		'brw_wm_state.c',
+		'brw_wm_surface_state.c',
+	])
+
+Export('i965simple')
diff --git a/src/mesa/pipe/softpipe/SConscript b/src/mesa/pipe/softpipe/SConscript
new file mode 100644
index 0000000000..d581ee8d3c
--- /dev/null
+++ b/src/mesa/pipe/softpipe/SConscript
@@ -0,0 +1,42 @@
+Import('*')
+
+env = env.Clone()
+
+softpipe = env.ConvenienceLibrary(
+	target = 'softpipe',
+	source = [
+		'sp_clear.c',
+		'sp_context.c',
+		'sp_draw_arrays.c',
+		'sp_flush.c',
+		'sp_prim_setup.c',
+		'sp_prim_vbuf.c',
+		'sp_quad_alpha_test.c',
+		'sp_quad_blend.c',
+		'sp_quad_bufloop.c',
+		'sp_quad.c',
+		'sp_quad_colormask.c',
+		'sp_quad_coverage.c',
+		'sp_quad_depth_test.c',
+		'sp_quad_earlyz.c',
+		'sp_quad_fs.c',
+		'sp_quad_occlusion.c',
+		'sp_quad_output.c',
+		'sp_quad_stencil.c',
+		'sp_quad_stipple.c',
+		'sp_query.c',
+		'sp_state_blend.c',
+		'sp_state_clip.c',
+		'sp_state_derived.c',
+		'sp_state_fs.c',
+		'sp_state_rasterizer.c',
+		'sp_state_sampler.c',
+		'sp_state_surface.c',
+		'sp_state_vertex.c',
+		'sp_surface.c',
+		'sp_tex_sample.c',
+		'sp_texture.c',
+		'sp_tile_cache.c',
+	])
+
+Export('softpipe')
\ No newline at end of file