Initial commit (gwm-basic 1.0).

1 files changed, 50 insertions, 0 deletions

diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..d209b9c
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,50 @@
+AC_INIT(gwm-basic, 1.0, gtw@gnu.org)
+AC_CONFIG_SRCDIR(gwm.c)
+AM_INIT_AUTOMAKE
+AC_CONFIG_FILES(Makefile)
+AC_CONFIG_HEADERS(config.h)
+
+AC_DEFINE(_GNU_SOURCE,1,Enable GNU extensions on systems that have them.)
+
+# Checks for programs:
+AC_PROG_CC
+PKG_PROG_PKG_CONFIG
+
+# Checks for libraries:
+#  pkg-config packages which must be present:
+packages="xcb"
+#  pkg-config xcb- packages which can optionally be used:
+optional_xcb_packages="shape"
+
+AC_ARG_WITH(shape,    [  --with-shape            use the X SHAPE extension.])
+
+AH_TEMPLATE(USE_SHAPE,[Use the X SHAPE extension.])
+
+for i in $optional_xcb_packages; do
+  AC_MSG_CHECKING([for $i])
+  if eval test "x\$with_$i" = xno; then
+    AC_MSG_RESULT(disabled)
+  else
+    iname=`echo $i | tr 'a-z' 'A-Z'`
+    PKG_CHECK_EXISTS( xcb-$i,
+    		      [AC_MSG_RESULT(yes)
+		      packages="$packages xcb-$i"
+		      AC_DEFINE_UNQUOTED(USE_$iname, 1)],
+		      [AC_MSG_RESULT(no)])
+  fi
+done
+
+AC_SEARCH_LIBS(iconv, iconv)
+
+# Checks for header files:
+AC_CHECK_HEADERS(iconv.h mcheck.h poll.h)
+
+# Checks for functions:
+AC_CHECK_FUNCS(iconv mtrace ppoll)
+
+PKG_CHECK_MODULES(XCB, $packages)
+
+AC_SUBST(XCB_CFLAGS)
+AC_SUBST(XCB_LIBS)
+
+AC_OUTPUT