AC_PREREQ(2.58)

AC_INIT(sphinx, 0.1, [/dev/null])
AM_INIT_AUTOMAKE([1.9 foreign no-dist-gzip dist-bzip2])

GETTEXT_PACKAGE=sphinx
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])

AC_CONFIG_SRCDIR(src/sphinx.h)
AC_CONFIG_HEADER(config.h)

AC_GNU_SOURCE

PKG_PROG_PKG_CONFIG
AC_PROG_CC
AC_PROG_LIBTOOL
IT_PROG_INTLTOOL([0.37.0])
AM_GLIB_GNU_GETTEXT


GTK_VERSION=2.14.0
GCONF_VERSION=2.14.0
PKG_CHECK_MODULES(DBG,
		  gconf-2.0 >= $GCONF_VERSION
		  gtk+-2.0 >= $GTK_VERSION
		  gtksourceview-2.0)
AC_SUBST(DBG_CFLAGS)
AC_SUBST(DBG_LIBS)

AC_PATH_PROG(GCONFTOOL, gconftool-2, no)

if test x"$GCONFTOOL" = xno; then
  AC_MSG_ERROR([gconftool-2 executable not found in your path - should be installed with GConf])
fi

AM_GCONF_SOURCE_2

GLIB_GENMARSHAL="$($PKG_CONFIG --variable=glib_genmarshal glib-2.0)"
AC_SUBST([GLIB_GENMARSHAL])
GLIB_MKENUMS="$($PKG_CONFIG --variable=glib_mkenums glib-2.0)"
AC_SUBST([GLIB_MKENUMS])

dnl ===========================================================================
dnl check compiler flags
AC_DEFUN([SPHINX_CC_TRY_FLAG], [
  AC_MSG_CHECKING([whether $CC supports $1])

  sphinx_save_CFLAGS="$CFLAGS"
  CFLAGS="$CFLAGS $1"

  AC_COMPILE_IFELSE([ ], [sphinx_cc_flag=yes], [sphinx_cc_flag=no])
  CFLAGS="$sphinx_save_CFLAGS"

  if test "x$sphinx_cc_flag" = "xyes"; then
    ifelse([$2], , :, [$2])
  else
    ifelse([$3], , :, [$3])
  fi
  AC_MSG_RESULT([$sphinx_cc_flag])
])


dnl Use lots of warning flags with with gcc and compatible compilers

dnl Note: if you change the following variable, the cache is automatically
dnl skipped and all flags rechecked.  So there's no need to do anything
dnl else.  If for any reason you need to force a recheck, just change
dnl MAYBE_WARN in an ignorable way (like adding whitespace)

MAYBE_WARN="-Wall -Wextra \
-Wsign-compare -Werror-implicit-function-declaration \
-Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
-Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
-Wpacked -Wswitch-enum -Wmissing-format-attribute \
-Wstrict-aliasing=2 -Winit-self -Wunsafe-loop-optimizations \
-Wdeclaration-after-statement -Wold-style-definition \
-Wno-missing-field-initializers -Wno-unused-parameter \
-Wno-attributes -Wno-long-long -Winline"


# invalidate cached value if MAYBE_WARN has changed
if test "x$sphinx_cv_warn_maybe" != "x$MAYBE_WARN"; then
	unset sphinx_cv_warn_cflags
fi
AC_CACHE_CHECK([for supported warning flags], sphinx_cv_warn_cflags, [
	echo
	WARN_CFLAGS=""

	# Some warning options are not supported by all versions of
	# gcc, so test all desired options against the current
	# compiler.
	#
	# Note that there are some order dependencies
	# here. Specifically, an option that disables a warning will
	# have no net effect if a later option then enables that
	# warnings, (perhaps implicitly). So we put some grouped
	# options (-Wall and -Wextra) up front and the -Wno options
	# last.

	for W in $MAYBE_WARN; do
		SPHINX_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
	done

	sphinx_cv_warn_cflags=$WARN_CFLAGS
	sphinx_cv_warn_maybe=$MAYBE_WARN

	AC_MSG_CHECKING([which warning flags were supported])])
WARN_CFLAGS="$sphinx_cv_warn_cflags"
CFLAGS="$CFLAGS $WARN_CFLAGS"


AC_CONFIG_FILES([
    Makefile
    sphinx.desktop.in
    src/Makefile
    po/Makefile.in
])

AC_OUTPUT