AC_INIT([Evince Browser Plugin],
        [0.1.0],
        [dbn.lists@gmail.com],
        [evince-browser-plugin])
AC_CONFIG_SRCDIR([src/evbp.c])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([foreign])
LT_INIT([disable-static])
PKG_PROG_PKG_CONFIG
m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])

dnl We want C99 features
AC_PROG_CC_C99

dnl Check for dependencies. Mozilla packages are split out because we
dnl only want their headers.
GTK_REQUIRED=2.14.0
GLIB_REQUIRED=2.18.0
EVINCE_API=2.32
mozilla_pkgs="mozilla-plugin nspr"
evince_pkgs="gtk+-2.0 >= $GTK_REQUIRED gio-2.0 >= $GLIB_REQUIRED \
    evince-view-$EVINCE_API evince-document-$EVINCE_API"
PKG_CHECK_MODULES([MOZILLA], [$mozilla_pkgs])
PKG_CHECK_MODULES([EVINCE], [$evince_pkgs])

GETTEXT_PACKAGE="$PACKAGE"
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
dnl AM_GLIB_GNU_GETTEXT
AC_DEFINE_UNQUOTED([G_LOG_DOMAIN], ["$PACKAGE"], [Logging prefix])

dnl Add extra C flags
AC_SUBST([E_CFLAGS])
AC_ARG_ENABLE([warnings],
              [AC_HELP_STRING([--disable-warnings],
                [C compiler warnings (default: yes)])],
              [warnings=$enableval],
              [warnings=yes])
if test "x$warnings" = xyes && test "x$GCC" = xyes; then
    E_CFLAGS="-Wall -Wmissing-prototypes -Wmissing-declarations \
-Wbad-function-cast"
    case `$CC -dumpversion` in
    3.4.* | 4.*)
        E_CFLAGS="$E_CFLAGS -Wold-style-definition \
-Wdeclaration-after-statement"
        ;;
    esac
fi

AC_CONFIG_FILES([
Makefile
src/Makefile
test/Makefile
test/firefox.sh
])

AC_CONFIG_COMMANDS([script],[
chmod +x test/firefox.sh
])

AC_OUTPUT