From dcc3a08a6650457c71bef6b3e8f952d05da74809 Mon Sep 17 00:00:00 2001
From: Will Thompson <resiak@soc.pidgin.im>
Date: Wed, 1 Aug 2007 23:33:59 +0000
Subject: Add .manager and .service; fix up some autofoo.

I stole a lot of the autotools stuff in this patch verbatim from
telepathy-gabble, and don't really understand it.  :-)  I tried and
failed to make gabble's AS_AC_EXPAND macro work, but it seems like I
can achieve the same goal with $(datadir)/dbus-1/services directly in
the relevant Makefile.am.

20070801233359-984d1-3ec7025633a8c59e8f563284b4c476c06351873c.gz
---
 m4/.git-darcs-dir  |  0
 m4/Makefile.am     |  2 ++
 m4/as-ac-expand.m4 | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
 3 files changed, 51 insertions(+)
 create mode 100644 m4/.git-darcs-dir
 create mode 100644 m4/Makefile.am
 create mode 100644 m4/as-ac-expand.m4

(limited to 'm4')

diff --git a/m4/.git-darcs-dir b/m4/.git-darcs-dir
new file mode 100644
index 0000000..e69de29
diff --git a/m4/Makefile.am b/m4/Makefile.am
new file mode 100644
index 0000000..d5293d7
--- /dev/null
+++ b/m4/Makefile.am
@@ -0,0 +1,2 @@
+EXTRA_DIST = \
+as-ac-expand.m4
diff --git a/m4/as-ac-expand.m4 b/m4/as-ac-expand.m4
new file mode 100644
index 0000000..deebd2b
--- /dev/null
+++ b/m4/as-ac-expand.m4
@@ -0,0 +1,49 @@
+dnl as-ac-expand.m4 0.2.0                                   -*- autoconf -*-
+dnl autostars m4 macro for expanding directories using configure's prefix
+
+dnl (C) 2003, 2004, 2005 Thomas Vander Stichele <thomas at apestaart dot org>
+
+dnl Copying and distribution of this file, with or without modification,
+dnl are permitted in any medium without royalty provided the copyright
+dnl notice and this notice are preserved.
+
+dnl AS_AC_EXPAND(VAR, CONFIGURE_VAR)
+
+dnl example:
+dnl AS_AC_EXPAND(SYSCONFDIR, $sysconfdir)
+dnl will set SYSCONFDIR to /usr/local/etc if prefix=/usr/local
+
+AC_DEFUN([AS_AC_EXPAND],
+[
+  EXP_VAR=[$1]
+  FROM_VAR=[$2]
+
+  dnl first expand prefix and exec_prefix if necessary
+  prefix_save=$prefix
+  exec_prefix_save=$exec_prefix
+
+  dnl if no prefix given, then use /usr/local, the default prefix
+  if test "x$prefix" = "xNONE"; then
+    prefix="$ac_default_prefix"
+  fi
+  dnl if no exec_prefix given, then use prefix
+  if test "x$exec_prefix" = "xNONE"; then
+    exec_prefix=$prefix
+  fi
+
+  full_var="$FROM_VAR"
+  dnl loop until it doesn't change anymore
+  while true; do
+    new_full_var="`eval echo $full_var`"
+    if test "x$new_full_var" = "x$full_var"; then break; fi
+    full_var=$new_full_var
+  done
+
+  dnl clean up
+  full_var=$new_full_var
+  AC_SUBST([$1], "$full_var")
+
+  dnl restore prefix and exec_prefix
+  prefix=$prefix_save
+  exec_prefix=$exec_prefix_save
+])
-- 
cgit v1.2.3