#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.57)
AC_INIT([linpicker], 3.1, [ewalsh@tycho.nsa.gov])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_SRCDIR([src/server.c])
AC_CONFIG_HEADERS([src/config.h])

AM_INIT_AUTOMAKE([dist-bzip2])

AC_DISABLE_STATIC
AC_PROG_LIBTOOL
AC_PROG_CC
AM_PROG_CC_C_O
LT_INIT

# Checks for pkg-config packages
PKG_CHECK_MODULES(DFB, directfb >= 1.4.2)
PKG_CHECK_MODULES(UDEV, libudev >= 145)
PKG_CHECK_MODULES(XCB, xcb)

# Doxygen support
DX_DOXYGEN_FEATURE(ON)
DX_HTML_FEATURE(ON)
DX_CHM_FEATURE(OFF)
DX_CHI_FEATURE(OFF)
DX_MAN_FEATURE(OFF)
DX_RTF_FEATURE(OFF)
DX_XML_FEATURE(OFF)
DX_PDF_FEATURE(OFF)
DX_PS_FEATURE(OFF)

DX_INIT_DOXYGEN([$PACKAGE_NAME], [Doxyfile], [doc/doxygen])

# Build options and defines
AC_ARG_ENABLE(loglevel,
	AS_HELP_STRING([--enable-loglevel=n], [Set log level [default=0]]),
	[LOGLEVEL=$enableval], [LOGLEVEL=0])

case $LOGLEVEL in
@<:@0-9@:>@) ;;
*) LOGLEVEL=0 ;;
esac
AC_DEFINE_UNQUOTED(LOGLEVEL, $LOGLEVEL, [Log level])

AC_ARG_ENABLE(socket,
	AS_HELP_STRING([--enable-socket], [Enable local socket interface [default=no]]),
	[LOCALSOCK=$enableval], [LOCALSOCK=no])

if test "x$LOCALSOCK" = xyes; then
	AC_DEFINE(LOCALSOCK, 1, [Enable local socket interface])
fi
AM_CONDITIONAL(LOCALSOCK, [test "x$LOCALSOCK" = xyes])

# Output
AC_CONFIG_FILES([Makefile src/Makefile libvchan/Makefile data/Makefile])
AC_OUTPUT