dnl  Copyright 2005 Red Hat, Inc.
dnl 
dnl  Permission to use, copy, modify, distribute, and sell this software and its
dnl  documentation for any purpose is hereby granted without fee, provided that
dnl  the above copyright notice appear in all copies and that both that
dnl  copyright notice and this permission notice appear in supporting
dnl  documentation, and that the name of Red Hat not be used in
dnl  advertising or publicity pertaining to distribution of the software without
dnl  specific, written prior permission.  Red Hat makes no
dnl  representations about the suitability of this software for any purpose.  It
dnl  is provided "as is" without express or implied warranty.
dnl 
dnl  RED HAT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
dnl  EVENT SHALL RED HAT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
dnl  PERFORMANCE OF THIS SOFTWARE.
dnl
dnl Process this file with autoconf to create configure.

# Initialize Autoconf
AC_PREREQ([2.60])
AC_INIT([sessreg], [1.1.3],
	[https://gitlab.freedesktop.org/xorg/app/sessreg/-/issues], [sessreg])
AC_CONFIG_SRCDIR([Makefile.am])
AC_CONFIG_HEADERS([config.h])
AC_USE_SYSTEM_EXTENSIONS
AC_SYS_LARGEFILE

# Initialize Automake
AM_INIT_AUTOMAKE([foreign dist-xz])

# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
m4_ifndef([XORG_MACROS_VERSION],
	  [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
XORG_MACROS_VERSION(1.8)
XORG_DEFAULT_OPTIONS
XORG_WITH_LINT

# Checks for header files.
AC_CHECK_HEADERS([lastlog.h pwd.h utmp.h utmpx.h sys/param.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_CHECK_MEMBERS([
	struct utmp.ut_host,
	struct utmp.ut_id,
	struct utmp.ut_pid,
	struct utmp.ut_type], [], [], [
	#include <sys/types.h>
	#include <utmp.h>
	])
AC_CHECK_MEMBERS([struct utmpx.ut_syslen], [], [], [#include <utmpx.h>])
AC_CHECK_TYPES([
	struct lastlog], [], [],[
	#include <sys/types.h>
	#ifdef HAVE_UTMP_H
	#include <utmp.h>
	#endif
	#ifdef HAVE_LASTLOG_H
	#include <lastlog.h>
	#endif
	])

# Checks for library functions.
AC_CHECK_FUNCS([pututline updwtmpx utmpxname])

# Obtain compiler/linker options for dependencies
PKG_CHECK_MODULES(SESSREG, [xproto >= 7.0.25])

AC_CONFIG_FILES([
	Makefile
	man/Makefile])
AC_OUTPUT